Trecho do ponto de entrada que faz a chamada para o Ponto de Entrada que o cliente renomeia para XMT103BDP

O fonte MT103BDP.prx (pasta 0-Pontos Entrada Protheus) apenas chama a função U_MLA103DP() (fonte MLA103DP.prw, pasta Pontos Entrada do projeto Central XML), que contém a regra:

User Function MLA103DP()
	Local   l103BDP     := .F.
	Local 	lUsaCXml 	:= GetNewPar("XM_USACXML",.T.)

	If lUsaCXml .And. INCLUI .And. Alltrim(cEspecie) $ "CTE" .And. FwIsInCallStack("U_XMLDCONDOR")
		If SF1->(FieldPos("F1_VALPEDG")) > 0  .And. sfValAtrib("nValPedagio") == "N".And. Len(aNfeDanfe) >= 15
			If nValPedagio > 0
				aNFEDanfe[15]	:= nValPedagio
				M->F1_VALPEDG	:= nValPedagio
				MaFisAlt("NF_VALPEDG",nValPedagio)
			Endif
		Endif
		// Atualiza a natureza
		If FwIsInCallStack("A116Inclui") .And. Type("cNatFin") <> "U" .And. !Empty(cNatFin)
			cNatureza 	:= cNatFin
			NfeVldRef("NF_NATUREZA",cNatureza)
		EndIf
	Endif

	// Permite a execução do ponto de entrada caso o cliente tenha o mesmo ponto customizado
	If ExistBlock("XMT103BDP")
		l103BDP:=ExecBlock("XMT103BDP",.F.,.F.,{})
		If ValType(l103BDP)<>'L'
			l103BDP := .F.
		EndIf
		Return l103BDP
	Endif

Return l103BDP

Uso na Central XML

• A Central XML não bloqueia a aba Duplicatas: o retorno padrão é .F.
• O ponto de entrada é usado apenas como gatilho na inclusão de CT-e pela Central XML (U_XMLDCONDOR):
  • grava o valor do pedágio do XML (nValPedagio) em aNFEDanfe[15] / F1_VALPEDG e recalcula o fiscal (MaFisAlt("NF_VALPEDG"));
  • no CT-e de compras (A116Inclui), atualiza a natureza financeira com a natureza informada na Central XML (cNatFin).
• Parâmetro XM_USACXML indica se a Central XML está em uso (padrão .T.).
• Compatibilização: o cliente que já tem o MT103BDP renomeia sua User Function para XMT103BDP. O retorno lógico dela define se o aCols de duplicatas será bloqueado.

Documentação oficial no TDN

MT103BDP - Bloqueio do Acols de Duplicatas

Ponto de entrada MT103BDP

Ponto de Entrada

Exemplo:

User Function MT103BDP()

Local lRet := .T.

Return lRet